全部显示

HyperlinkPart 方法

       

HyperlinkPart 方法返回存储为“超链接”数据类型的数据的信息。String 型。

expression.HyperlinkPart(Hyperlink, Part)

expression   必需。返回“Applies To”列表中的一个对象的表达式。

Hyperlink  必需 Variant 型。其值为存储在“超链接”字段中的数据的 Variant 变量。

Part  可选 AcHyperlinkPart。part 参数的值是一个固有常量，代表希望由 HyperlinkPart 方法返回的信息。

说明

使用 HyperlinkPart 方法可以返回“超链接”字段的三个值中的一个或返回显示的值。返回值取决于 part 参数的设置。part 参数是可选的。如果没有指定，则函数返回 Microsoft Access 所显示的超链接的值（对应于 part 参数的 acDisplayedValue 设置）。返回的值可以是“超链接”字段的四个部分（displaytext、address、subaddress 或 screentip）中的一个部分、完整的地址、 address#subaddress 或 Microsoft Access 所显示的超链接的值。

注意  如果要在查询中使用 HyperlinkPart 方法，则 part 参数是必需的，并且不能使用上面列出的常量值而必须用实际数值。

当“超链接”字段的 displaytext 部分有一个值时，Microsoft Access 显示的值将与 displaytext 的设置相同。如果“超链接”字段的 displaytext 部分没有值，则所显示的值为“超链接”字段的 address 或 subaddress 部分（这取决于哪个值首先出现在字段中）。

下表列出了 HyperlinkPart 方法返回的、存储在“超链接”字段中的数据的值。

超链接字段数据 HyperlinkPart 方法返回值
#http://www.microsoft.com# acDisplayedValue：http://www.microsoft.com

acDisplayText：

acAddress：http://www.microsoft.com

acSubAddress：

acScreenTip：

acFullAddress：http://www.microsoft.com
Microsoft#http://www.microsoft.com# acDisplayedValue：Microsoft

acDisplayText：Microsoft

acAddress: http://www.microsoft.com

acSubAddress：

acScreenTip：

acFullAddress：http://www.microsoft.com
客户#http://www.microsoft.com#窗体客户 acDisplayedValue：客户

acDisplayText：客户

acAddress：http://www.microsoft.com

acSubAddress：窗体客户

acScreenTip：

acFullAddress：http://www.microsoft.com#窗体客户
##窗体客户#输入信息 acDisplayedValue：窗体客户

acDisplayText：

acAddress：

acSubAddress：窗体客户

acScreenTip：输入信息

acFullAddress：#窗体客户

当您通过“插入超链接”对话框（单击“插入”菜单中的“超链接”命令可打开该对话框）或直接在“超链接”字段中键入一个地址部分来添加“超链接”字段的 address 部分时，Microsoft Access 将添加两个 # 符号以分隔超链接数据的各部分。

要添加或编辑超链接字段的 displaytext 部分，可用鼠标右键单击表、窗体或报表中的超链接，指向快捷菜单上的“超链接”，然后在“要显示的文字”框中键入要显示的文本。

当向“超链接”字段直接添加数据时，必须包含两个 # 符号以分隔超链接数据的各个部分。

示例

下面的示例使用全部四个 part 参数常量来显示由 HyperlinkPart 方法返回的、关于包含“超链接”字段的表中每条记录的信息。若要试用该示例，可将 DisplayHyperlinkParts 过程粘贴到模块的“声明”节。然后即可在“调试”窗口调用 DisplayHyperlinkParts 过程，调用时传给过程的参数为包含超链接的表的名称和包含“超链接”数据的字段的名称。例如：

:DisplayHyperlinkParts "MyHyperlinkTableName", "MyHyperlinkFieldName"

Public Sub DisplayHyperlinkParts(ByVal strTable As String, _
                                 ByVal strField As String)
    
    Dim rst As New ADODB.Recordset
    Dim strMsg As String

        
    rst.Open strTable, CurrentProject.Connection, _
             adOpenForwardOnly, adLockReadOnly

    ' For each record in table.
    Do Until rst.EOF
        strMsg = "DisplayValue = " _
            & HyperlinkPart(rst(strField), acDisplayedValue) _
            & vbCrLf & "DisplayText = " _
            & HyperlinkPart(rst(strField), acDisplayText) _
            & vbCrLf & "Address = " _
            & HyperlinkPart(rst(strField), acAddress) _
            & vbCrLf & "SubAddress = " _
            & HyperlinkPart(rst(strField), acSubAddress) _
            & vbCrLf & "ScreenTip = " _
            & HyperlinkPart(rst(strField), acScreenTip) _
            & vbCrLf & "Full Address = " _
            & HyperlinkPart(rst(strField), acFullAddress)
            
        ' Show parts returned by HyperlinkPart function.
        MsgBox strMsg
        rst.MoveNext
    Loop
    
End Sub

如果要在查询中使用 HyperlinkPart 方法，则 part 参数是必需的。例如，下面的 SQL 语句使用 HyperlinkPart 方法返回在链接表的 URL 字段上以“超链接”数据类型存储的数据的信息：

SELECT Links.URL, HyperlinkPart([URL],0)
    AS Display, HyperlinkPart([URL],1)
    AS Name, HyperlinkPart([URL],2)
    AS Addr, HyperlinkPart([URL],3)
    AS SubAddr, HyperlinkPart([URL],4)
    AS ScreenTip
    FROM Links