全部显示

AppIcon 属性

使用 AppIcon 属性可以指定包含应用程序图标的位图 (.bmp) 文件或图标 (.ico) 文件的文件名。例如，可以使用 AppIcon 属性指定一个包含汽车图片的 .bmp 文件，来代表一个汽车部件数据库应用程序。

设置

AppIcon 属性是一个字符串表达式，代表一个有效的位图或图标文件的文件名（包括路径）。

设置该属性最简单的方法是使用“启动”对话框中的“应用程序图标”选项。单击“工具”菜单上的“启动”，即会显示“启动”对话框。也可以使用宏或 Visual Basic 设置该属性。

若要使用宏或 Visual Basic 设置 AppIcon 属性，首先必须已经在“启动”对话框中设置过该属性，或者使用以下方式创建该属性：

• 在 Microsoft Access 数据库 (.mdb) 中，可以通过使用 CreateProperty 方法添加该属性，并将其追加到 Database 对象的 Properties 集合中。
• 在 Microsoft Access 项目 (.adp) 中，可以通过使用 Add 方法将该属性添加到 CurrentProject 对象的 AccessObjectProperties 集合中。

若要立即看到所做的更改，还必须使用 RefreshTitleBar 方法。

说明

如果要发布应用程序，建议将包含图标的 .bmp 或 .ico 文件与其 Microsoft Access 应用程序放在同一个目录中。

如果未设置 AppIcon 属性或者属性值无效，则会显示 Microsoft Access 图标。

在代码中对该属性进行设置（只要代码中包含 RefreshTitleBar 方法）或者关闭“启动”对话框之后，该属性设置立即生效。

示例

下面的示例显示如何在一个 Microsoft Access 数据库 (.mdb) 中更改 AppIcon 属性和 AppTitle 属性。如果尚未创建这两个属性或者还没有对这两个属性进行设置，必须先使用 CreateProperty 方法创建这两个属性，并将其添加到 Properties 集合中。

Sub cmdAddProp_Click()
    Dim intX As Integer
    Const DB_Text As Long = 10
    intX = AddAppProperty("AppTitle", DB_Text, "My Custom Application")
    intX = AddAppProperty("AppIcon", DB_Text, "C:\Windows\Cars.bmp")
    CurrentDb.Properties("UseAppIconForFrmRpt") = 1
    Application.RefreshTitleBar
End Sub

Function AddAppProperty(strName As String, _
        varType As Variant, varValue As Variant) As Integer
    Dim dbs As Object, prp As Variant
    Const conPropNotFoundError = 3270

    Set dbs = CurrentDb
    On Error GoTo AddProp_Err
    dbs.Properties(strName) = varValue
    AddAppProperty = True

AddProp_Bye:
    Exit Function

AddProp_Err:
    If Err = conPropNotFoundError Then
        Set prp = dbs.CreateProperty(strName, varType, varValue)
        dbs.Properties.Append prp
        Resume
    Else
        AddAppProperty = False
        Resume AddProp_Bye
    End If
End Function