全部显示

PrtMip 属性

       

在 Visual Basic 中使用 PrtMip 属性可以设置或返回“打印”对话框中针对窗体或报表指定的设备模式信息。

expression.PrtMip

expression   必需。返回“Applies To”列表中的一个对象的表达式。

说明

PrtMip 属性设置是一个 28 字节的结构,对应的是“页面设置”对话框的“边距”选项卡中对窗体或报表的设置。

PrtMip 属性有以下成员:

成员 说明
LeftMargin、RightMargin、TopMargin、BottomMargin Long 值,用于指定页边缘和打印的项之间以为单位的距离。
DataOnly 指定打印元素的 Long 值。为 True 时,只打印“数据表”视图、窗体或报表中的表数据或查询数据,不打印标签、控件的边框和网格线,而且显示诸如线条和方框等图形。为 False 时,打印数据、标签及图形。
ItemsAcross Long 值,用于指定多列报表或标签中的列数。该成员与“页面设置”对话框“列”选项卡中“网格设置”下的“列数”框的值是相等的。
RowSpacing Long 值,以磅的 1/20 为单位,指定主体节间的水平间距。
ColumnSpacing Long 值,以缇为单位,指定主体节间的垂直间距。
DefaultSize Long 值。为 True 时,使用“设计”视图中主体节的大小;为 False 时,使用 ItemSizeWidth 和 ItemSizeHeight 成员指定的值。
ItemSizeWidth Long 值,以缇为单位,指定主体节的宽度。该成员与“页面设置”对话框“列”选项卡中“列尺寸”下的“宽度”框的值相同。
ItemSizeHeight Long 值,以缇为单位,指定主体节的宽度。该成员与“页面设置”对话框“列”选项卡中“列尺寸”下的“高度”框的值相等。
ItemLayout Long 值,用于指定水平 (1953) 或垂直 (1954) 的列布局。该成员与“页面设置”对话框“列”选项卡中“列布局”下的“先行后列”或“先列后行”选项分别相同。
FastPrint 保留。
Datasheet 保留。

PrtMip 属性设置在“设计”视图中可读写,而在其他视图中则为只读。

示例

下面的 PrtMip 属性示例演示如何设置具有两个水平列的报表。

Private Type str_PRTMIP
    strRGB As String * 28
End Type

Private Type type_PRTMIP
    xLeftMargin As Long
    yTopMargin As Long
    xRightMargin As Long
    yBotMargin As Long
    fDataOnly As Long
    xWidth As Long
    yHeight As Long
    fDefaultSize As Long
    cxColumns As Long
    yColumnSpacing As Long
    xRowSpacing As Long
    rItemLayout As Long
    fFastPrint As Long
    fDatasheet As Long
End Type

Public Sub PrtMipCols(ByVal strName As String)

    Dim PrtMipString As str_PRTMIP
    Dim PM As type_PRTMIP
    Dim rpt As Report
    Const PM_HORIZONTALCOLS = 1953
    Const PM_VERTICALCOLS = 1954
    
    ' Open the report.
    DoCmd.OpenReport strName, acDesign
    Set rpt = Reports(strName)
    PrtMipString.strRGB = rpt.PrtMip
    LSet PM = PrtMipString
    
    ' Create two columns.
    PM.cxColumns = 2
    
    ' Set 0.25 inch between rows.
    PM.xRowSpacing = 0.25 * 1440
    
    ' Set 0.5 inch between columns.
    PM.yColumnSpacing = 0.5 * 1440
    PM.rItemLayout = PM_HORIZONTALCOLS
    
    ' Update property.
    LSet PrtMipString = PM
    rpt.PrtMip = PrtMipString.strRGB
    
    Set rpt = Nothing
    
End Sub

下一个 PrtMip 属性示例显示如何将全部页边距设为 1 英寸。

Public Sub SetMarginsToDefault(ByVal strName As String)

    Dim PrtMipString As str_PRTMIP
    Dim PM As type_PRTMIP
    Dim rpt As Report
    
    ' Open the report.
    DoCmd.OpenReport strName, acDesign
    Set rpt = Reports(strName)
    PrtMipString.strRGB = rpt.PrtMip
    LSet PM = PrtMipString
    
    ' Set margins.
    PM.xLeftMargin = 1 * 1440
    PM.yTopMargin = 1 * 1440
    PM.xRightMargin = 1 * 1440
    PM.yBotMargin = 1 * 1440
    
    ' Update property.
    LSet PrtMipString = PM
    rpt.PrtMip = PrtMipString.strRGB
    
    Set rpt = Nothing
    
End Sub