OnPageOpen 事件

在打开网页时发生。

pPage  必选，PageWindowEx 类型。PageWindowEx 对象。

注释

OnPageOpen 事件与 Application 对象相关联。当用户打开网页时，Microsoft FrontPage 会打开网页的框架集并且触发默认框架集的 OnPageOpen 事件。然后 FrontPage 会执行事件过程中指定的代码。

注意  OnPageOpen 事件只会为默认框架集触发，即使网页上还有其他框架。OnPageOpen 事件只会在网页并未打开的状态下触发。

示例

本示例在文档在 PageWindowEx 对象中打开时更改 FPHTMLDocument 对象的标题。

注意  若要运行本示例，必须至少打开一个站点。本示例使用 Rogue Cellars 作为指定的站点，将 Zinfandel.htm 作为指定的网页。您可以创建称为 Rogue Cellars 的站点以及称为 Zinfandel.htm 的网页，或可用您选择的站点和网页来代替。

创建一个称为 frmLaunchEvents.frm 的表单并添加两个按钮，分别称为 cmdOpenPage 和 cmdCancel。将下列代码添加到表单代码窗口的 Declarations 部分。

Option Explicit
Private WithEvents eFPApplication As Application

将下列代码添加到代码窗口的 UserForm_Initialize 部分。

Private Sub UserForm_Initialize()
    Set eFPApplication = New Application
End Sub

将下列代码添加到代码窗口的 cmdAddPage_Click 部分。

Private Sub cmdAddPage_Click()
    Dim myPageWindows As PageWindows
    Dim myFile As String

    Set myPageWindows = ActiveWeb.ActiveWebWindow.PageWindows
    myFile = _
        "file:///C:/My Documents/My Webs/Rogue Cellars/Zinfandel.htm"
    myPageWindows.Add (myFile)
End Sub

将下列代码添加到代码窗口的 cmdCancel_Click 部分。

Private Sub cmdCancel_Click()
    'Hide the form.
    frmLaunchEvents.Hide
    Exit Sub
End Sub

将下列代码添加到代码窗口的 eFPApplication_OnPageOpen 部分。

Private Sub eFPApplication_OnPageOpen(ByVal pPage As _
        PageWindow)
    Dim myDoc As FPHTMLDocument

    Set myDoc = pPage.ActiveDocument

    myDoc.Title = "Rogue Cellars Home Page"
End Sub