Delete 方法

从 NavigationNodes 集合中的可用节点列表中删除单个导航节点。

expression.Delete(Index)

expression 必选。返回 NavigationNodes 对象的表达式。

Index 可选。Variant 类型。引用导航结构中的项目。可以是对应于导航结构中的项目的任何数字，索引从零开始。

从 Properties 集合的可用属性列表中删除属性。

expression.Delete(PropertyKey)

expression 必选。返回 Properties 对象的表达式。

PropertyKey 必选，String 类型。代表属性名称的字符串。

从 Webs 集合中的可用站点列表删除站点。

expression.Delete(WebDeleteFlags)

expression 必选。返回上述对象之一的表达式。

WebDeleteFlags 可选，FpWebDeleteFlags 常数。决定从当前站点中删除的内容。

FpWebDeleteFlags 可以是下列这些 FpWebDeleteFlags 常数之一。

fpDeleteEntireWeb 默认

fpDeleteFrontPageInfoFromWeb

从 WebFiles 集合中的可用任务列表删除任务，或者从 WebFolders 集合中的可用文件夹列表删除一个或多个文件夹。

expression.Delete(Index)

expression 必选。返回上述对象的之一的表达式。

Index 必选，Variant 类型。引用 WebFiles 或 WebFolders 集合中的项目。可以是对应于集合中的项目的任何数字，索引从零开始。

从 Webs 集合中的可用站点列表删除站点。

expression.Delete(Index, WebDeleteFlags)

expression 必选。返回 Webs 对象的表达式。

Index 必选，Variant 类型。引用 Webs 集合的对象。可以是对应于集合中的项目的任何数字，索引从零开始。

WebDeleteFlags 可选，FpWebDeleteFlags 常数。决定从当前站点删除的内容。

FpWebDeleteFlags 可以是下列这些 FpWebDeleteFlags 常数之一。

fpDeleteEntireWeb 默认

fpDeleteFrontPageInfoFromWeb

从站点中删除指定对象。

expression.Delete

expression 必选。返回上述对象之一的表达式。

本示例删除活动站点中第二个文件的第四个导航节点。

注意若要使更改应用于站点，必须将导航结构应用于该站点。

Private Sub DeleteNavNode()
    Dim myWeb As WebEx
    Dim myChildNodes As NavigationNodes

    Set myWeb = ActiveWeb
    Set myChildNodes = _
        myWeb.RootFolder.WebFiles(1).NavigationNode.Children

    Call myChildNodes.Delete(3)
    myWeb.ApplyNavigationStructure
End Sub

本示例从文件 Sales.htm 删除 SaleText 属性。

Private Sub DeleteProperty()
    Dim myFile As WebFile
    Dim myProp As String

    Set myFile = ActiveWeb.RootFolder.Files("Sales.htm")
    myFile.Properties.Delete ("SaleText")
End Sub

本示例删除临时站点 TempWeb。

注意若要运行本示例，必须有一个称为“C:\My Documents\My Webs\TempWeb”（对于在 Microsoft Windows 上运行的服务器）或“C:\WINNT\Profiles\logon alias\Personal\My Webs\TempWeb”（对于在 Windows NT 上运行的服务器）的文件。在这两种情况下，都可以用另一个站点 URL 来代替。

Private Sub DeleteWeb()
    Dim myWeb As WebEx
    Dim myTempWeb As WebEx
    Dim myFolders As WebFolders
    Dim myFolder As WebFolder
    Dim myWebToDelete As String

    Set myWeb = Webs.Open("C:\My Documents\My Webs")
    Set myFolders = myWeb.RootFolder.Folders
    myWebToDelete = "TempWeb"

    For Each myFolder In myFolders
    If myFolder.IsWeb = True Then
        If myFolder.Name = myWebToDelete Then
            Set myTempWeb = Webs.Open(myFolder.Name)
            myTempWeb.Delete
        End If
    End If
    Next
    ActiveWebWindow.Close
End Sub

本语句删除活动站点中的文件。

注意若要运行本示例，必须有一个称为“C:\My Documents\My Webs\TempFile.htm”（对于在 Microsoft Windows 上运行的服务器）或“C:\WINNT\Profiles\logon alias\Personal\My Webs\TempFile.htm”（对于在 Windows NT 上运行的服务器）的文件。在这两种情况下，都可以用另一个站点 URL 来代替。

ActiveWeb.RootFolder.Files.Delete "TempFile"

本语句删除活动站点中的第二个文件夹。

ActiveWeb.RootFolder.Folders.Delete(1)

本语句删除第四个站点。

Webs.Delete(3)

本示例从活动站点删除一个文件。

注意若要运行本示例，必须有一个称为“C:\My Documents\My Webs\TempFile.htm”（对于在 Microsoft Windows 上运行的服务器）或“C:\WINNT\Profiles\logon alias\Personal\My Webs\TempFile.htm”（对于在 Windows NT 上运行的服务器）的文件。在这两种情况下，都可以用另一个站点 URL 来代替。

Private Sub DeleteFile()
    Dim myFile As WebFile

    Set myFile = ActiveWeb.RootFolder.Files("TempFile")
    myFile.Delete

End Sub

本示例从活动站点删除一个文件夹。

注意若要运行本示例，必须有一个称为“C:\My Documents\My Webs\TempFolder” （对于在 Microsoft Windows 上运行的服务器）或“C:\WINNT\Profiles\logon alias\Personal\My Webs\TempFolder”（对于在 Windows NT 上运行的服务器）的文件。在这两种情况下，都可以用另一个站点 URL 来代替。

Private Sub DeleteFolder()
    Dim myFolder As WebFolder

    Set myFolder = ActiveWeb.RootFolder.Folders("TempFolder")
    myFolder.Delete

End Sub