Properties 集合对象

多个对象 Properties

类似 Property 对象的 meta 数据构成的集合。Properties 集合中的每个项目代表了与单个 WebEx、WebFile 或 WebFolder 对象相关联的项目。有关详细信息，请参阅使用 PropertyKeys 中的 PropertyKeys。请由下列的列表中选择一个主题，便能直接进入该主题的内容。

使用 Properties 对象

在 Web 中使用 Properties 集合

使用 PropertyKeys

使用 Properties 对象

使用 Add 方法将属性添加到 Properties 集合对象。下列的语句将版权声明添加到 Properties 集合对象。

ActiveWeb.Properties.Add "Copyright", _
    “Copyright 1999 by Rogue Cellars”)

您也可以添加以及删除分类和审批级别。

使用 ApplyChanges 方法来应用已经添加到 Properties 集合对象的 Property 对象。下列的语句添加及应用版权属性至 Properties 集合对象。

ActiveWeb.Properties.Add "Copyright", _
    “Copyright 1999 by Rogue Cellars”)
ActiveWeb.Properties.ApplyChanges

使用 Count 属性来返回 Properties 集合对象中属性的总数。下列示例用来检查自从 Copyright 属性添加以及应用于集合对象后，Properties 集合对象中属性增加的数量，然后将版权添加到 Web 页。

注意  若要运行此示例，您必须有一个名为“C:\My Documents\My Webs\Rogue Cellars”的站点 (运行 Microsoft Windows 的服务器) 或“C:\WINNT\Profiles\logon alias\Personal\My Webs\Rogue Cellars”(运行 Windows NT 的服务器)。在两种情况下，您都可用其他站点 URL 或文件来替代。

Private Sub copyrightAdd()
    Dim myWeb As WebEx
    Dim myCopyright As String
    Dim myCount As Integer
    Dim myMessage As String

    myCopyright = "Copyright 1999 by Rogue Cellars"
    myCount = ActiveWeb.Properties.Count
    myMessage = "No new properties have been added."

    Set myWeb = Webs.Open("C:\My Webs\Rogue Cellars")
    myWeb.Activate
    ActiveWeb.Properties.Add "Copyright", myCopyright

    If myCount <> ActiveWeb.Properties.Count – 1 Then
        MsgBox myMessage
        Exit Sub
    End If

    ActiveWeb.RootFolder.Files("Zinfandel.htm").Open
    ActiveDocument.body.insertAdjacentText "BeforeEnd", _
        ActiveWeb.Properties("Copyright")
    ActivePageWindow.Save
    ActiveWeb.Close
End Sub

使用 Delete 方法删除单个属性。下列的语句将 Copyright 属性从 Properties 集合对象删除。

ActiveWeb.Properties.Delete("Copyright")

当您想要返回 Properties 集合对象的容器时，请使用 parent 属性。例如，下列的语句返回父站点的 URL。

myParentURL  = ActiveWeb.Properties.Parent.Url

在站点中使用 Properties 集合

使用 Properties(index) 来返回单个属性，其中 index 是 properties 集合对象中项目的 PropertyKey。下列的示例返回 PropertyKey vti_hassearchbot 的值。

Private Sub CheckForSearchBot()
    Dim myProperties As Properties
    Dim myFoundSearchBot As Boolean

    Set myProperties = ActiveWeb.Properties

    With myProperties
        myFoundSearchBot = .Item("vti_hassearchbot")
    End With
End Sub

要点  属性的值是不同类型的，也就是说，每一个值可以是字符串、布尔值或数组。您可以使用 Typename() 函数来确定属性值的类型。

注意  若要运行以下示例，您必须创建一个包含名为 txtCategories 的文本框的表单。此外，请注意 myCategories 在此示例中被声明为 variant 类型。在前一示例中，myFoundSearchBot 被声明为 Boolean，但也可以将其声明为字符串。

Private Sub GetWebPropertyCategories()
    Dim myProperties As Properties
    Dim myCategories As Variant
    Dim myCategory As Variant
    Dim txtCategories As String

    Set myProperties = ActiveWeb.Properties

    With myProperties
        myCategories = .Item("vti_categories")
        For Each myCategory In myCategories
            txtCategories = txtCategories & "|" & myCategory
        Next
    End With
End Sub

使用 PropertyKeys

属性关键字可以是组织站点信息的一个很有价值的工具。例如，您可以向自己站点中的主类别列表中添加类别。

要点  向类别列表中添加类别名称时区分大小写，但类别名称显示在用户界面 (UI) 时不区分大小写。因此，就会出现用户在客户端创建诸如“Web Administrators”的类别，但此名称已经以“web administrators”的方式存在于服务器上的情况。在这种情况下，在用户界面 (UI) 中，FrontPage 会将这两个类别都指定为“web administrators”类别，且它们二者都无法从站点 (在 UI 中) 中删除。在程序设计上，区分大小写可在 Visual Basic 编辑器的 Immediate 和 Local 窗口正确显示。

下列示例首先会将类别添加到活动站点的属性中，从相同的列表 (vti_categories) 删除 Waiting 类别，然后将新的类别添加到活动站点的每一个文件。

注意   创建新类别时，您必须首先将新的类别添加到站点，然后才能将其添加到文件。AddCategories 过程会将一个新的类别添加到站点，而下一个过程 AddCategoryToFiles 会将同一类别添加到站点中所有文件。

Private Sub AddCategories()
    Dim myWeb As WebEx
    Dim myCategory(2) As String
    Dim myItem As Variant

    Set myWeb = ActiveWeb
    myCategory(0) = "+web administrators"
    myCategory(1) = "-waiting"
    ActiveWeb.Properties("vti_categories") = myCategory
    ActiveWeb.Properties.ApplyChanges

    'List all of the items in vti_categories in the Immediate window
    For Each myItem In myWeb.Properties("vti_categories")
        Debug.Print myItem
    Next
End Sub

Private Sub AddCategoryToFiles()
    Dim myWeb As WebEx
    Dim myCategories(1) As String
    Dim myFiles As WebFiles
    Dim myFile As WebFile
    Dim myItem As Variant

    Set myWeb = ActiveWeb
    Set myFiles = myWeb.RootFolder.Files
    myCategories(0) = "+web administrators"

    For Each myFile In myFiles
        myFile.Properties("vti_categories") = myCategories
        myFile.Properties.ApplyChanges
        'List all the items in vti_categories in the Immediate window
        For Each myItem In myFile.Properties("vti_categories")
            Debug.Print myItem
        Next
    Next
End Sub

注意  虽然您可以创建例如“web administrators”的新类别，但这些新类别并不包含于安装 FrontPage 时自动创建的类别中。在它们被添加到站点之前，这些新类别在用户界面 (UI) 中是不可见的。请注意在前一示例中，新类别只有首先被添加到站点，然后才能在 UI 中可见。

下列的表格提供了关于 FrontPage 2000 中可用的属性关键字的详细信息。请注意所有 FrontPage 中的属性关键字都是以“vti_”开头的。我们建议您在要添加的属性关键字之前加上一个短的名称，例如单位名称的缩写，来降低与其他属性的命名发生冲突的机会。