MinimumValue 属性

返回或设置 Variant 类型的值，该值指定此域允许的最小值。此属性相当于在用户界面的“修改域”对话框中设置“允许的最小值”域。可读写。

expression  必选。返回“应用于”列表中的对象之一的表达式。

说明

如果此域输入非法信息，则将向用户显示错误信息。使用 MaximumValue 属性值设置此域的最大值。

示例

以下示例显示站点的第一个列表中 fpFieldNumber 和 fpFieldCurrency 类型的所有域的名称和最小值。

Sub DisplayMinimum()
'Displays the minimum value of all ListFieldNumber
'and ListFieldCurrency fields in the list

    Dim objApp As FrontPage.Application
    Dim objLstFlds As ListFields
    Dim strName As String
    Dim objLstFld As Object
    Dim strValues As String

    Set objApp = FrontPage.Application
    Set objLstFlds = objApp.ActiveWeb.Lists.Item(0).Fields
    'Cycle through lists and add value to string
    For Each objLstFld In objLstFlds
        If (objLstFld.Type = fpFieldNumber) Or (objLstFld.Type = fpFieldCurrency) Then
            strValues = strValues & objLstFld.Name & vbTab & _
                        objLstFld.MinimumValue & vbCr
        End If
    Next objLstFld

    If strValues <> "" Then
        MsgBox "The fields and their minimum values are:" & vbCr & _
                vbCr & strValues
    Else
        MsgBox "There are no ListFieldNumber or ListFieldCurrency Fields in the current list."
    End If

End Sub

以下示例将列表中 fpListFieldNumber 类型的所有域的最小值更改为常数 200。

注意 使用 ApplyChanges 方法来应用对列表所做的更改。

Sub ChangeMinimum()
'Changes minimum value for all fields of type
'ListFieldNumber

    Dim objApp As FrontPage.Application
    Dim objLstFlds As ListFields
    Dim strName As String
    Dim objLstFld As Object
    Const varMin As Variant = 1

    Set objApp = FrontPage.Application
    If objApp.ActiveWeb.Lists.Count > 0 Then
        Set objLstFlds = objApp.ActiveWeb.Lists.Item(0).Fields
        'Cycle through lists and change values
        For Each objLstFld In objLstFlds
            If objLstFld.Type = fpFieldNumber Then
                objLstFld.MinimumValue = varMin
            End If
        Next objLstFld
        objApp.ActiveWeb.Lists(0).ApplyChanges
    Else
        MsgBox "The active web contains no lists."
    End If
End Sub