本主题中的某些内容可能不适用于某些语言。
可用“Office 助手”气球为用户提供信息。气球中的信息可以是一条简单的消息、希望了解详细信息的请求信息或供用户选择的一列选项。创建、显示、关闭和修改“Office 助手”气球的一系列操作只能在运行时间进行。
下表包括了大多数常用的属性和方法,用于修改新建(空白)气球或原有气球的外观或功能。使用 Show 方法时气球将被显示或刷新;对气球所作的修改将在下次使用 Show 方法时显示出来。
属性或方法 | 说明 |
---|---|
Heading | 指定出现在“Office 助手”气球顶部的加粗文字。 |
Text | 指定出现在“Office 助手”气球体中的文本。该文本出现在标题之后但在复选框、标签或按钮之前。 |
Labels | 返回气球中标签的集合。标签的格式由 BalloonType 属性决定。标签出现在气球中的文本之后。可为标签列表设置编号或项目符号,同时该列表也可以是一系列按钮。与复选框不同的是,用户只须单击一个按钮即可记录该按钮对应的选项。 |
CheckBoxes | 返回气球中复选框的集合。用户可选中复选框,然后单击气球底部适当的按钮(例如,“确定”或“下一个”按钮)以记录其选择。 |
Close | 关闭并取消一个非模态气球,但不释放该对象变量。赋予该气球的对象变量仍然有效,因此可以重新显示该气球,或对它进行修改并在随后显示。本方法只能用于非模态气球。 |
Show | 向用户显示气球及其中所有的对象。本方法只能用于 Balloon 对象,对 Assistant 对象可使用 Visible 属性。 |
以下示例可实现:创建一个气球,该气球帮助用户选择打印机。本示例还提供了一个复选框选项,以帮助用户跳过气球中的信息。
Set bln = Assistant.NewBalloon
With bln
.Heading = "Instructions for Choosing a Printer."
.Text = "Click OK when you've chosen a printer."
lblTxt = "From the File menu, choose Print."
.Labels(1).Text = lblTxt
.Labels(2).Text = "Click Setup."
.Labels(3).Text = "Select the name of the printer."
.CheckBoxes(1).Text = "Skip this information."
.BalloonType = msoBalloonTypeNumbers
.Mode = msoModeModal
.Button = msoButtonSetOK
.Show
End With
用 Assistant 对象的 NewBalloon 属性可新建一个气球。新创建的气球是空白的,可用 Heading 属性添加一个标题,然后用 Text 属性在气球体中添加文字,还可根据需要添加控件。最后,用 Show 方法显示该气球。Show 方法在包含该方法的语句出现时立即显示气球,因此在设置完该气球的其他属性后,应该立即使用本方法。以下示例可实现:新建一个气球,然后设置标题和正文,并创建三个可供用户选择的复选框控件。
With Assistant.NewBalloon
.Button = msoButtonSetOkCancel
.Heading = "Regional Sales Data"
.Text = "Select a region"
For i = 1 To 3
.CheckBoxes(i).Text = "Region " & i
Next
.Show
End With
“Office 助手”中没有 Balloons 集合。要对多个气球进行管理,可为创建的各个气球分别设置对象变量,然后在需要时引用变量。此外,也可创建一个 Balloon 对象变量的数组,并给每个数组元素指定一个气球。以下示例可实现:创建一个数组并给该数组添加三个空白的 Balloon 对象。
Dim myBalloonArray(3) As Balloon
With Assistant
For i = 1 To 3
Set myBalloonArray(i) = .NewBalloon
Next
End With