AddPolyline 方法

在画布上添加一个开放或封闭的多边形。返回一个代表该多边形的 Shape 对象，并将其添加到 CanvasShapes 集合。

expression.AddPolyline(SafeArrayOfPoints)

expression 必需。该表达式返回一个 CanvasShapes 对象。

SafeArrayOfPoints Variant 类型，必需。指定折线顶点的坐标对数组。

在文档中添加一个开放或封闭的多边形。返回一个代表该多边形的 Shape 对象，并将其添加到 Shapes 集合。

expression.AddPolyline(SafeArrayOfPoints, Anchor)

expression 必需。该表达式返回“应用于”列表中的一个对象。

SafeArrayOfPoints Variant 类型，必需。指定折线顶点的坐标对数组。

Anchor Variant 类型，可选。代表折线所连接的文本的 Range 对象。如果指定 Anchor，则锁定标记位于锁定区域第一段的起始位置。如果忽略该参数，Word 将自动选择锁定区域，而直线则相对于页面的上部和左侧边缘进行定位。

说明

若要构造一个封闭多边形，应为折线的最后一个顶点和第一个顶点指定相同的坐标。

示例

本示例在新画布上创建一个 V 形开放多边形。

Sub NewCanvasPolyline()
    Dim docNew As Document
    Dim shpCanvas As Shape
    Dim sngArray(1 To 3, 1 To 2) As Single

    'Creates a new document and adds a drawing canvas
    Set docNew = Documents.Add
    Set shpCanvas = docNew.Shapes.AddCanvas( _
        Left:=100, Top:=75, Width:=200, Height:=300)

    'Sets the coordinates of the array
    sngArray(1, 1) = 100
    sngArray(1, 2) = 75
    sngArray(2, 1) = 150
    sngArray(2, 2) = 100
    sngArray(3, 1) = 100
    sngArray(3, 2) = 125

    'Adds a V-shaped open polyline to the drawing canvas
    shpCanvas.CanvasItems.AddPolyline SafeArrayOfPoints:=sngArray
End Sub

本示例在新文档中添加一个三角形。由于三角形的最后一个顶点和第一个顶点具有相同的坐标，因此该多边形是封闭的并且被填充的。

Sub NewPolyline()
    Dim arrayTriangle(1 To 4, 1 To 2) As Single
    Dim docNew As Document

    Set docNew = Documents.Add

    'Sets the coordinates of the array
    arrayTriangle(1, 1) = 25
    arrayTriangle(1, 2) = 100
    arrayTriangle(2, 1) = 100
    arrayTriangle(2, 2) = 150
    arrayTriangle(3, 1) = 150
    arrayTriangle(3, 2) = 50
    arrayTriangle(4, 1) = 25
    arrayTriangle(4, 2) = 100

    'Adds a closed polygon to the document
    docNew.Shapes.AddPolyline SafeArrayOfPoints:=arrayTriangle
End Sub