Item 方法

本示例选定活动文档中名为“temp”的书签。

Sub BookmarkItem()
    If ActiveDocument.Bookmarks.Exists("temp") = True Then
        ActiveDocument.Bookmarks.Item("temp").Select
    End If
End Sub

本示例在活动文档的第一段之上插入双边框。

Sub BorderItem()
    ActiveDocument.Paragraphs(1).Borders.Item(wdBorderTop) _
        .LineStyle = wdLineStyleDouble
End Sub

本示例显示“页面设置”对话框。

Sub DialogItem()
    Application.Dialogs.Item(wdDialogFileDocumentLayout).Display
End Sub

本示例显示 Documents 集合的第一篇文档的名字。

Sub DocumentItem()
    If Documents.Count >= 1 Then
        MsgBox Documents.Item(1).Name
    End If
End Sub

本示例在活动文档中创建首页页眉并设置其格式。

Sub HeadFootItem()
    ActiveDocument.PageSetup.DifferentFirstPageHeaderFooter = True
    With ActiveDocument.Sections(1).Headers _
            .Item(wdHeaderFooterFirstPage).Range
        .InsertBefore "Sales Report"
        With .Font
            .Bold = True
            .Size = "15"
            .Color = wdColorBlue
        End With
        .Paragraphs.Alignment = wdAlignParagraphCenter
    End With
End Sub

本示例首先清除名为“Colors”的下拉型窗体域中的各项，然后添加两个颜色名。Item 方法用来显示下拉型窗体域的第一个颜色。

Sub ListEntryItem()
    Dim d As DropDown
    Set d = ActiveDocument.FormFields.Add _
        (Range:=Selection.Range, _
        Type:=wdFieldFormDropDown).DropDown
    With d.ListEntries
        .Add Name:="Black"
        .Add Name:="Green"
    End With
    MsgBox d.ListEntries.Item(1).Name
End Sub