返回一个 Range 对象,该对象引用下一个文字部分,如下表所示。
文字部分 的类型 |
用 NextStoryRange 方法返回的项目 |
---|---|
wdMainTextStory、wdFootnotesStory、wdEndnotesStory 和 wdCommentsStory | 总是返回 Nothing |
wdTextFrameStory | 下一组链接文本框的文字部分 |
wdEvenPagesHeaderStory、wdPrimaryHeaderStory、wdEvenPagesFooterStory、wdPrimaryFooterStory、wdFirstPageHeaderStory、wdFirstPageFooterStory | 下一节中相同类型的文字部分 |
expression.NextStoryRange
expression 必需。该表达式返回一个 Range 对象。
本示例向活动文档中前两节的偶数页页眉中添加文本。
If ActiveDocument.Sections.Count >= 2 Then
With ActiveDocument
.PageSetup.OddAndEvenPagesHeaderFooter = True
.Sections(1).Headers(wdHeaderFooterEvenPages) _
.Range.Text = "Even Header 1"
.Sections(2).Headers(wdHeaderFooterEvenPages) _
.LinkToPrevious = False
.StoryRanges(wdEvenPagesHeaderStory) _
.NextStoryRange.Text = "Even Header 2"
End With
End If
本示例在活动文档的每个文字部分中搜索文字“Microsoft Word”。如果找到的话,本示例将倾斜格式应用于该文字。
For Each myStoryRange In ActiveDocument.StoryRanges
myStoryRange.Find.Execute _
FindText:="Microsoft Word", Forward:=True
While myStoryRange.Find.Found
myStoryRange.Italic = True
myStoryRange.Find.Execute _
FindText:="Microsoft Word", Forward:=True
Wend
While Not (myStoryRange.NextStoryRange Is Nothing)
Set myStoryRange = myStoryRange.NextStoryRange
myStoryRange.Find.Execute _
FindText:="Microsoft Word", Forward:=True
While myStoryRange.Find.Found
myStoryRange.Italic = True
myStoryRange.Find.Execute _
FindText:="Microsoft Word", Forward:=True
Wend
Wend
Next myStoryRange